Удвоить буквы в каждом слове строки - Assembler

ASSUME CS:CSEG,DS:DSEG
 
; Символы возврата каретки и перевода строки.
CRLF EQU 0Dh,0Ah
 
; Максимальный допустимый размер вводимой строки с учетом символа возврата
; каретки. Размер должен быть в пределах от 1 до 254 (см. описание DOS Fn 0Ah).
MAX_STR_SIZE EQU 40
 
DSEG SEGMENT BYTE
; Сообщения пользователю.
title   DB CRLF,'Doubling of Letters in Words',CRLF,CRLF,'$'
prompt  DB 'Please, enter a string and then press Enter to complete:',CRLF,'$'
info    DB CRLF,'The following is the resulting string:',CRLF,'$'
warning DB 'The entered string is empty, there is nothing to print!','$'
 
; Разделители (список можно изменять по желанию).
delimiters LABEL BYTE
  ; Пробельные символы: табуляция, пробел.
  DB 09h,20h
  ; Знаки препинания.
  DB ',.!?;:"'''
  ; Скобки.
  DB '(){}[]<>'
  ; Математические знаки.
  DB '+=-'
numOfDelimiters=$-delimiters
 
; Буфер для сохранения строки, введенной пользователем. Буфер имеет формат,
; требуемый для фукции буферизированного ввода строки со стандартного
; устройства ввода (см. описание DOS Fn 0Ah).
buf LABEL BYTE
  ; Максиммально допустимый размер строки с учетом символа возврата каретки.
  maxSize DB MAX_STR_SIZE
  ; Длина строки без учета символа возврата каретки.
  len     DB 0
  ; Сама строка.
  itself  DB MAX_STR_SIZE DUP (?)
DSEG ENDS
 
CSEG SEGMENT
START:
  mov ax,DSEG
  mov ds,ax
 
  ; Выводим приглашение для ввода строки.
  mov dx,OFFSET prompt
  mov ah,09h
  int 21h
 
  ; Получаем адрес буфера, в который будем вводить строку.
  mov di,OFFSET buf
 
  ; Вводим строку в буфер.
  mov dx,di
  mov dx,OFFSET buf
  mov ah,0Ah
  int 21h
 
  ; Проверяем, что строка не является пустой.
  inc di                   ; Сдвигаемся к адресу байта, где хранится длина.
  xor bx,bx                ; (Тоже самое, что mov bx,0)
  mov bl,BYTE PTR [di]     ; Считываем значение длины строки.
  test bx,bx               ; Длина не равна нулю? (Тоже, самое что cmp bx,0)
  jz EMPTY_STRING          ; Переходим, если длина равна нулю (строка пустая).
  
  ; Выводим пояснение.
  mov dx,OFFSET info
  mov ah,09h
  int 21h
 
  xor dx,dx
OUTPUT_NEXT_CHAR:
  ; Выводим очередной символ строки в первый раз.
  inc di                   ; Сдвигаемся к адресу первого байта строки.
  mov dl,BYTE PTR [di]     ; Считываем первый символ строки.
  mov ah,02h
  int 21h
 
  ; Проверяем, что очередной символ не является разделителем.
  mov si,OFFSET delimiters ; Адрес начала массива разделителей.
  mov cx,numOfDelimiters   ; Получаем количество разделителей.
CHECK_NEXT_DELIMITER:
  lodsb                    ; Загружаем очередной разделителя.
  cmp al,dl                ; Является ли символ строки разделителем?
  ;test al,dl
  jz CHAR_IS_DELIMITER     ; Если символ строки является разделителем, то
                           ; прерываем проверку. Символ повторно не печатаем.
  loop CHECK_NEXT_DELIMITER; Иначе, продолжаем проверку.
 
  ; Если очередной символ строки не является разделителем, то выводим этот
  ; символ во второй раз.
  mov ah,02h
  int 21h
 
CHAR_IS_DELIMITER:
 
  ; Проверяем, отсались ли еще символы в строке.
  dec bx                   ; Уменьшаем счетчик символов в строке.
  jz EXIT                  ; Если достигли конца строки, выходим из программы.
  jmp OUTPUT_NEXT_CHAR     ; Иначе выводим следующий символ.
 
EMPTY_STRING:
  ; Выводим предупреждение о пустой строке.
  mov dx,OFFSET warning
  mov ah,09h
  int 21h
 
EXIT:
  mov ax,4C00h
  int 21h
CSEG ENDS
END START