Деревья: количество листьев на заданном подуровне + удаление узлов - PascalABC.NET

type
  PTree = ^TTree;
  TTree = record
    Data : integer;
    L, R : PTree;
  end;
  
procedure Add(var Root : PTree; v : integer);
 
  procedure Create(var p : PTree; info : integer);
  begin
    new(p);
    p^.Data := info; p^.L := nil; p^.R := nil;
  end;
  
begin
  if Root = nil then Create(Root, v)
  else if Root^.Data < v then Add(Root^.R, v)
  else if Root^.Data > v then Add(Root^.L, v);
end;
 
procedure Print(Root : PTree; level : integer := 0);
begin
  if Root <> nil then
  begin
    Print(Root^.L, level + 1);
    writeln('':2*level, Root^.Data);
    Print(Root^.R, level + 1);
  end
end;
 
function ItemLevel(Root : PTree; lvl : integer; currLevel : integer := 0) : integer;
begin
  if Root <> nil then
  begin
    if lvl = currLevel then Result := 1
    else Result := ItemLevel(Root^.L, lvl, currLevel + 1) + 
                   ItemLevel(Root^.R, lvl, currLevel + 1);
  end
  else Result := 0;
end;
 
procedure DeleteTree(var Root: PTree);
Begin
  if Root <> nil then
  begin
    DeleteTree(Root^.R);
    DeleteTree(Root^.L);
    Dispose(Root);
    Root := nil;
  end;
end;
 
procedure FindToRemove(var Root : PTree; v : integer);
begin
  if Root^.Data = v then DeleteTree(Root)
  else if (Root^.L <> nil) and (Root^.L^.Data = v) then DeleteTree(Root^.L)
  else if (Root^.R <> nil) and (Root^.R^.Data = v) then DeleteTree(Root^.R)
  else
    if v < Root^.Data then FindToRemove(Root^.L, v)
    else FindToRemove(Root^.R, v);
end;
  
var 
  R : PTree = nil;
  lvl, st : integer;
begin
  for var i := 1 to 20 do Add(R, Random(100));
  Print(R);
  
  write('level = '); readln(lvl);
  writeln('items on level ', lvl, ' : ', ItemLevel(R, lvl));
  write('subtree to remove: '); readln(st);
  FindToRemove(R, st);
  Print(R);
  
  DeleteTree(R);
end.