Изменение угла от Pi до 2Pi - PascalABC.NET

Формулировка задачи:

type
  TVector2D = record
  private 
    _X, _Y: real;
    
    function GetLen() := Sqrt(Sqr(_X) + Sqr(_Y));
    
    function GetAngle() := ArcCos(_X / GetLen());
    
  public 
    property X: real read _X write _X;
    property Y: real read _Y write _Y;
    property Len: real read GetLen; // Длина вектора
    property Angle: real read GetAngle; // Угол поворота вектора
    
    constructor(cx, cy: real);
    begin
      X := cx;Y := cy;
    end;
    
    function Mult(v: TVector2D) := _X * v.X + _Y * v.Y; // Возвращает скалярное произведение векторов.
    
    function IsCollinear(v: TVector2D) := _X * v.Y - v.X * _Y = 0; // Возвращает true, если векторы являются коллинеарными.
    
    procedure operator *=(v: TVector2D; k: real);
    begin
      v.X *= k;
      v.Y *= k;
    end;
    
    procedure operator +=(v, v1: TVector2D);
    begin
      v.X += v1.X;
      v.Y += v1.Y;
    end;
    
    class function VectorI() := new TVector2D(1, 0);
    
    class function VectorJ() := new TVector2D(0, 1);
    
    class function VectorSum(vectors: array of TVector2D): TVector2D; // Возвращает вектор, получаемый суммированием всех векторов, указанных в параметрах.
    begin
      Result := new TVector2D(0, 0);
      foreach var vector in vectors do
        Result := Result + vector;
    end;
    
    class function Readln() := new TVector2D(ReadlnInteger('X:'), ReadlnInteger('Y:'));
    
    class function operator *(v: TVector2D; k: real) := new TVector2D(v.X * k, v.Y * k);
    
    class function operator +(v, v1: TVector2D) := new TVector2D(v.X + v1.X, v.Y + v1.Y);
    
    class function operator-(a: TVector2D) := new TVector2D(-a.X, -a.Y); // Возвращает новый вектор с координатами (-X, -Y).
    
    class function operator=(a, b: TVector2D) := (a.X = b.X) and (a.Y = b.Y);
    
    class function operator<>(a, b: TVector2D) := not (a = b);
    
    function ToString() := Format('Vector({0}, {1})', _X, _Y);
    
    procedure Print() := Write(ToString());
    
    procedure Println() := Writeln(ToString());
  end;
 
begin
  var V1 := new TVector2D(-1, -1);
  RadToDeg(V1.Angle).ToString().Println();
end.

Как изменить функцию GetAngle, чтобы угол менялся в пределах от 0 до 2*Pi, а не до Pi? Угол определяется между положительным направлением оси X и радиус-вектором.

Решение задачи: «Изменение угла от Pi до 2Pi»

Листинг программы

function Ugol(a,b:point):real;
begin
if (b.x>a.x)and(b.y<=a.y) then Ugol:=arctan((a.y-b.y)/(b.x-a.x)){I четверть}
else if (b.x>a.x)and(b.y>a.y) then Ugol:=arctan((a.y-b.y)/(b.x-a.x))+2*pi{IV четверть}
else if b.x<a.x then  Ugol:=arctan((a.y-b.y)/(b.x-a.x))+pi{II-III четверти}
else if b.x=a.x then
 begin
  if b.y<a.y then  Ugol:=pi/2{вертикально вверх}
  else if b.y>a.y then Ugol:=3*pi/2{вертикально вниз}
  else Ugol:=0;
 end;
end;

Объяснение кода листинга программы

Список изменений угла в зависимости от положения точек:

I четверть: угол между положительной осью X и положительной осью Y, а также между положительной осью X и отрицательной осью Y равен arctan((a.y-b.y)/(b.x-a.x)).
II-III четверти: угол между отрицательной осью X и положительной осью Y, а также между отрицательной осью X и отрицательной осью Y равен arctan((a.y-b.y)/(b.x-a.x))+pi.
IV четверть: угол между положительной осью X и положительной осью Y, а также между положительной осью X и отрицательной осью Y равен arctan((a.y-b.y)/(b.x-a.x))+2*pi.
Вертикально вверх: угол между положительной осью X и положительной осью Y равен pi/2.
Вертикально вниз: угол между положительной осью X и отрицательной осью Y равен 3*pi/2.
Угол между положительной осью X и положительной осью Y равен 0.
Угол между положительной осью X и отрицательной осью Y равен 2*pi.