Какой признак подобия треугольников лучше использовать при заданной реализации? - PascalABC.NET

type
  TVector2D = record
  private 
    _X, _Y: real;
    
    function GetLen() := Sqrt(Sqr(_X) + Sqr(_Y));
  
  public 
    property X: real read _X write _X;
    property Y: real read _Y write _Y;
    property Len: real read GetLen; // Длина вектора
    
    constructor(cx, cy: real);
    begin
      X := cx;Y := cy;
    end;
    
    function Mult(v: TVector2D) := _X * v.X + _Y * v.Y; // Возвращает скалярное произведение векторов.
    
    function VectorMultAbs(v: TVector2D) := Abs(_X * v.Y - _Y * v.X);
    
    function IsCollinear(v: TVector2D) := _X * v.Y - v.X * _Y = 0; // Возвращает true, если векторы являются коллинеарными.
    
    procedure operator *=(v: TVector2D; k: real);
    begin
      v.X *= k;
      v.Y *= k;
    end;
    
    procedure operator +=(v, v1: TVector2D);
    begin
      v.X += v1.X;
      v.Y += v1.Y;
    end;
    
    class function VectorI() := new TVector2D(1, 0);
    
    class function VectorJ() := new TVector2D(0, 1);
    
    class function VectorSum(vectors: array of TVector2D): TVector2D; // Возвращает вектор, получаемый суммированием всех векторов, указанных в параметрах.
    begin
      Result := new TVector2D(0, 0);
      foreach var vector in vectors do
        Result := Result + vector;
    end;
    
    class function Readln() := new TVector2D(ReadlnInteger('X:'), ReadlnInteger('Y:'));
    
    class function operator *(v: TVector2D; k: real) := new TVector2D(v.X * k, v.Y * k);
    
    class function operator +(v, v1: TVector2D) := new TVector2D(v.X + v1.X, v.Y + v1.Y);
    
    class function operator -(v, v1: TVector2D) := new TVector2D(v.X - v1.X, v.Y - v1.Y);
    
    class function operator-(a: TVector2D) := new TVector2D(-a.X, -a.Y); // Возвращает новый вектор с координатами (-X, -Y).
    
    class function operator=(a, b: TVector2D) := (a.X = b.X) and (a.Y = b.Y);
    
    class function operator<>(a, b: TVector2D) := not (a = b);
    
    function ToString() := Format('Vector({0}, {1})', _X, _Y);
    
    procedure Print() := Write(ToString());
    
    procedure Println() := Writeln(ToString());
  end;
 
type
  TTriangle = record
  private
    _VecA, _VecB, _VecC: TVector2D;
  
  function GetSquare() := (_VecC - _VecA).VectorMultAbs(_VecB - _VecA) * 0.5;
  
  function GetPerimeter() := (_VecB - _VecA).Len + (_VecB - _VecC).Len + (_VecA - _VecC).Len;
  
  public
    {Точки определил векторами для возможности применения всех операций определенных в классе вектора к точкам.}
    property VecA: TVector2D read _VecA write _VecA; // Вектор, определяющий положение точки A
    property VecB: TVector2D read _VecB write _VecB; // Вектор, определяющий положение точки B
    property VecC: TVector2D read _VecC write _VecC; // Вектор, определяющий положение точки C
    property Square: real read GetSquare; // Площадь
    property Perimeter: real read GetPerimeter; // Периметр

    constructor(vA, vB, vC: TVector2D);
    begin
      VecA := vA;
      VecB := vB;
      VecC := vC;
    end;
    
    function IsSimilar(t: TTriangle): boolean;
    begin
      
    end;
    
    function ToString() := Format('Triangle({0}, {1}, {2})', _VecA.ToString(), _VecB.ToString(), _VecC.ToString());
    
    procedure Print() := Write(ToString());
    
    procedure Println() := Writeln(ToString());
  end;
  
begin
  (new TTriangle(new TVector2D(0, 0), new TVector2D(10, 0), new TVector2D(0, 10))).Perimeter.ToString().Println();
end.