Заполнить матрицу по спирали - PascalABC.NET (249458)

var a : array [,] of Integer;
 
procedure SetN(var Row : Integer; dRow : Integer; var Col : Integer; dCol : Integer; var n : Integer);
begin
  Row += dRow; Col += dCol; n += 1; a[Row, Col] := n;
end;
 
procedure fillToDown(Row, Col, n : Integer); forward;
procedure fillToLeft(Row, Col, n : Integer); forward;
procedure fillToUp  (Row, Col, n : Integer); forward;
 
procedure fillToRight(Row, Col, n : Integer);
begin
  while (Col < a.GetLength(1)-1) and (a[Row, Col+1] = 0) do SetN(Row, 0, Col, +1, n);
  if n < a.Length then fillToDown(Row, Col, n);
end;
 
procedure fillToDown(Row, Col, n : Integer);
begin
  while (Row < a.GetLength(0)-1) and (a[Row+1, Col] = 0) do SetN(Row, +1, Col, 0, n);
  if n < a.Length then fillToLeft(Row, Col, n);
end;
 
procedure fillToLeft(Row, Col, n : Integer);
begin
  while (Col > 0) and (a[Row, Col-1] = 0) do SetN(Row, 0, Col, -1, n);
  if n < a.Length then fillToUp(Row, Col, n);
end;
 
procedure fillToUp(Row, Col, n : Integer);
begin
  while (Row > 0) and (a[Row-1, Col] = 0) do SetN(Row, -1, Col, 0, n);
  if n < a.Length then fillToRight(Row, Col, n);
end;
 
begin
  var n := ReadInteger('n =');
  SetLength(a, n, n);
  fillToRight(0, -1, 0);
  a.Println;
end.