Игра Конвея Жизнь на Лампанели - Assembler

;Игра Конвея "Жизнь" во вселенной 16*8 с топологией тора
TABLE:               ;Таблица "номер_бита->маска"
DATA    01           ;NOP  Проедемся по данным, как по коду
DATA    02           ;NOP  Проедемся по данным, как по коду
DATA    04           ;NOP  Проедемся по данным, как по коду
DATA    08           ;NOP  Проедемся по данным, как по коду
DATA    10           ;NOP  Проедемся по данным, как по коду
DATA    20           ;NOP  Проедемся по данным, как по коду
DATA    40           ;NOP  Проедемся по данным, как по коду
DATA    80           ;NOP  Проедемся по данным, как по коду
MAIN:
MOV     @KOLONIJA, R2
MOV     R2, R1
OUT     (R2)+, P0    ;Вывод колонии на лампы Лампанели
OUT     (R2)+, P1
OUT     (R2)+, P2
OUT     (R2)+, P3
OUT     (R2)+, P4
OUT     (R2)+, P5
OUT     (R2)+, P6
OUT     (R2)+, P7
MOV     R2, R0
@:
MOV     (R1)+, (R2)+ ;Копирование текущей колонии в предыдущую
CMP     R0, R1
JNZ     @
MOV     FE, R3       ;Здесь будем перебирать клетки вселенной (7F..0)*2
SCAN:
XOR     R2, R2       ;Здесь будем считать соседей
CALL    SOSED_PRAVEE ;Есть ли сосед справа ?
SUB     20, R3
CALL    SOSED        ;Есть ли сосед справа-сверху ?
ADD     2, R3
CALL    SOSED        ;Есть ли сосед сверху ?
ADD     2, R3
CALL    SOSED        ;Есть ли сосед слева-сверху ?
ADD     20, R3
CALL    SOSED        ;Есть ли сосед слева ?
ADD     20, R3
CALL    SOSED        ;Есть ли сосед слева-снизу ?
CALL    SOSED_PRAVEE ;Есть ли сосед снизу ?
CALL    SOSED_PRAVEE ;Есть ли сосед справа-снизу ?
SUB     1E, R3       ;Вернемся к своей клетке
CALL    OFFS_MASK
ADD     BE, R1       ;Лампанель ADD @KOLONIJA,R1 не понимает
CMP     2, R2        ;Условия :
JZ      @@           ; если соседей < 2, то смерть от одиночества
OR      R0, (R1)     ;Рождение
CMP     3, R2        ; если соседей > 3, то смерть от перенаселения
JZ      @@           ; если у пустой клетки соседей 3, то заселение
XOR     R0, (R1)     ;Смерть
@@:
SUB     2, R3        ;Следующая клетка
JGE     SCAN         ;Последняя ?
JMP     MAIN         ;Следующий шаг Жизни
 
OFFS_MASK:           ;Из номера клетки в R3 смещение в R1 и маску в R0
MOV     R3, R1
SHL     8, R1        ;Топология вселенной Жизни - тор
SHR     C, R1
MOV     R3, R0
AND     E, R0
MOV     (R0), R0     ;Чтение маски из таблицы
RET
 
SOSED_PRAVEE:
SUB     2, R3
SOSED:
CALL    OFFS_MASK
ADD     CE, R1       ;Лампанель ADD @KOLONIJA_DO,R1 не понимает
AND     (R1), R0     ;Клетка пустая или заселенная ?
JZ      @@@
ADD     1, R2        ;Нашли еще одного соседа
@@@:
RET
 
KOLONIJA:            ;Начальная и следующая колония (тут адрес BE):
DATA    0            ;Caterer
DATA    200          ;
DATA    8F0          ; (поставщик)
DATA    880          ; -
DATA    800          ; осциллятор
DATA    100          ;
DATA    600          ; периода
DATA    0            ; 3
KOLONIJA_DO:
;Тут адрес CE. Далее восемь слов под предыдущую колонию,
; пятнадцать неиспользованных слов и два слова под стек