Нужно исправить ошибку в программе - Turbo Pascal

Формулировка задачи:

Код программы:

program zad3;
label l1;
type mas=array [1..50] of integer;
mas1=array [1..100] of integer;
var
 
a,b : mas;
c : mas1;
i, j,k,fl,n,m:byte;
procedure sort(a:integer; var arr: mas);{процедура сортировки по возрастанию методом пузырька}
var i,j,k:integer;
begin
    for i := 1 to a-1 do
        for j := 1 to a-i do
            if arr[j] > arr[j+1] then begin
                k := arr[j];
                arr[j] := arr[j+1];
                arr[j+1] := k
            end;
end;
procedure concat(a,b:mas; n,m:integer; var arr: mas1);{процедура формирования масива с из двух отсортированных}
var i,j,k:integer;
begin
 i:=1;
 j:=1;
 k:=1;
 while(k<n+m) do
  begin
   while((a[i]<=b[j])and(i<=n))do {запись в массив с элементов массива а,пока не найдётся элемент больший, чем в массиве b}
     begin
      c[k]:=a[i];
      inc(k);
      inc(i);
     end;
   while((b[j]<=a[i])and(j<=m))do{запись в массив с элементов массива b,пока не найдётся элемент больший, чем в массиве a}
     begin
      c[k]:=b[j];
      inc(k);
      inc(j);
     end;
  if((j>m)and(i<n)) then{запись в массив с оставшихся элементов массива а}
     while(i<=n)do
     begin
      c[k]:=a[i];
      inc(k);
      inc(i);
     end;
   if((i>n)and(j<m))then{запись в массив с оставшихся элементов массива b}
      while(j<=m)do
     begin
      c[k]:=b[j];
      inc(k);
      inc(j);
     end;
  end;   
end;
begin
 
l1: writeln ('Vvedite razmer vektora a(<=50)');{ввод количества элементов массива а}
 readln(n);
 writeln ('Vvedite razmer vektora b(<=50)');{ввод количества элементов массива b}
 readln(m);
 if(n>50)or(n<1)or(m>50)or(n<1)then {проверка допустимых значений}
  begin
   writeln ('Nekorrektnie vhodnie dannie');
   goto l1;
  end; 
 for i:=1 to n do  {формирование исходного массива а }
     readln(a[i]);
 for j:=1 to m do  {формирование исходного массива b }
     readln(b[j]);
 
 sort(n,a);{сортировка массива а}
 sort(m,b);{сортировка массива b}
 concat(a,b,n,m,c);
 {вывод искомого массива с}
 writeln ('Itogovii massiv C:');
 for i:=1 to n+m do  
   write (c[i]:8,'');
end.

Суть ошибки:

При вводе больших чисел, при заполнении массивов, последний максимальные элемент обнуляется.

Решение задачи: «Нужно исправить ошибку в программе»

Листинг программы

  procedure concat(a, b: mas; n, m: integer; var arr: mas1);
  {процедура формирования масива с из двух отсортированных}
  var
    i, j, k: integer;
  begin
    i := 1;
    j := 1;
    k := 1;
    {Пока в обоих массивах есть элементы - вставлять элемент в итоговый.}
    while (i <= n) and (j <= m) do
    begin
      if a[i] < b[j] then
      begin
        c[k] := a[i];
        Inc(i);
      end else
      begin
        c[k] := b[j];
        Inc(j);
      end;
      Inc(k);
    end;
    {Теперь в одном из массивов элементов нет, а в другом остались.
     Делаем два цикла для дозаписи "хвоста" - один выполнится, а другой - нет.}
    while (i <= n) do
    begin
      c[k] := a[i];
      Inc(i);
      Inc(k);
    end;
    while (j <= m) do
    begin
      c[k] := b[j];
      Inc(j);
      Inc(k);
    end;
  end;

Объяснение кода листинга программы

В процедуре concat используются три переменные: a, b и arr. Переменная arr является выходным массивом, который будет содержать итоговый отсортированный массив.
Переменные i, j и k инициализируются значениями 1. Они будут использоваться для сравнения элементов массивов a и b и вставки их в массив arr.
В цикле while проверяется, что оба массива a и b не пусты. Если это условие выполняется, то происходит сравнение элементов массивов a и b.
Если элемент a[i] меньше элемента b[j], то его значение копируется в массив arr, инкрементируется значение переменной i и увеличивается значение переменной k. Это делается для того, чтобы элементы массива a были расположены в начале массива arr.
Если элемент a[i] больше элемента b[j], то его значение копируется в массив arr, инкрементируется значение переменной j и увеличивается значение переменной k. Это делается для того, чтобы элементы массива b были расположены в конце массива arr.
После выполнения цикла while, в одном из массивов (a или b) не останется элементов, а в другом останутся. Поэтому выполняются два дополнительных цикла while.
Первый цикл while выполняется для дозаписи хвоста массива arr, который остался после выполнения предыдущего цикла while. В этом цикле элементы массива a копируются в массив arr.
Второй цикл while выполняется для дозаписи хвоста массива arr, который остался после выполнения первого цикла while. В этом цикле элементы массива b копируются в массив arr.
По завершении всех циклов, массив arr будет содержать отсортированный массив, сформированный из элементов массивов a и b.