Начало работы с асмом - Assembler

Узнай цену своей работы

Формулировка задачи:

Народ, кто понимает ассемблер.... есть код проги, допустим, в блокноте. Из него сделать асм-файл - норм. Захожу в командную строку, нахожу этот файл, пишу: ml /е: / coff 2222.asm - obj После чего выдает сообщение, что мл не является приложением Win32, а потом отказ в доступе( как исправить ошибку? Если проблема в адресации,то я не знаю как это проверить. Помогите, пожалуйста)

Решение задачи: «Начало работы с асмом»

textual
Листинг программы
@echo off
 
if exist "EnumWindows.exe" del "EnumWindows.exe"
if not exist rsrc.rc goto over1
 
echo /////////////////////////////////////////////////////////////////////////////
\masm32\bin\rc /v rsrc.rc
if errorlevel 1 goto errrc
 
echo /////////////////////////////////////////////////////////////////////////////
\masm32\bin\cvtres /machine:ix86 rsrc.res
if errorlevel 1 goto errcvt
 
:over1
 
echo /////////////////////////////////////////////////////////////////////////////
\masm32\bin\ml /c /coff "EnumWindows.asm"
if errorlevel 1 goto errasm
 
if not exist rsrc.obj goto nores
echo /////////////////////////////////////////////////////////////////////////////
\masm32\bin\Link /SUBSYSTEM:WINDOWS /OPT:NOREF "EnumWindows.obj" rsrc.obj
if errorlevel 1 goto errlink
 
goto TheEnd
 
:nores
echo /////////////////////////////////////////////////////////////////////////////
\masm32\bin\Link /SUBSYSTEM:WINDOWS /OPT:NOREF "EnumWindows.obj"
if errorlevel 1 goto errlink
 
goto TheEnd
 
:errrc
echo -----------------------------------------------------------------------------
echo Error Resource Compiler
pause
goto TheEnd
 
:errcvt
echo -----------------------------------------------------------------------------
echo Error Resource To Object Converter
pause
goto TheEnd
 
:errlink
echo -----------------------------------------------------------------------------
echo Error Incremental Linker
pause
goto TheEnd
 
:errasm
echo -----------------------------------------------------------------------------
echo Error Macro Assembler
pause
goto TheEnd
 
:TheEnd
if exist "rsrc.aps" del "rsrc.aps"
if exist "rsrc.obj" del "rsrc.obj"
if exist "rsrc.res" del "rsrc.res"
if exist "EnumWindows.obj"   del "EnumWindows.obj"

Оцени полезность:

6   голосов , оценка 4.167 из 5
Похожие ответы