Ввод данных на уже открытую Web страницу - VBA

Формулировка задачи:

Добрый день! Существует задача : нужно заполнить уже открытую страницу в InternetExplorer данными с листа Excel. Создать новый экземпляр IE через CreateObject, открыть страницу и заполнить данными у меня получается, а вот подключится к уже открытому приложению ну никак не выходит. Я пробовал через GetObject! Может у кого есть ответы?

Решение задачи: «Ввод данных на уже открытую Web страницу»

textual
                            Листинг программы 
                        

                            Sub Procedure_1()
 
    'Для работы этого кода надо подключить библиотеку:
    'Tools - References... - Microsoft Internet Controls.
    
    'Здесь указывается название программы Internet Explorer.
    Const sApplicationName As String = "Windows Internet Explorer"
 
    'ShellWindows - это открытые папки компьютера и
    'окна программы Internet Explorer.
    'Для поздего связывания: CreateObject("Shell.Application").Windows
    Dim oShellWindows As New SHDocVw.ShellWindows
    
    Dim oIE As SHDocVw.WebBrowser
    Dim bFlag As Boolean
    
    'Узнаём, запущен ли IE, чтобы не было ошибок.
    If oShellWindows.Count = 0 Then
        MsgBox "IE не открыт!", vbCritical
        Exit Sub
    End If
    
    'Смотрим, открыта ли программа Internet Explorer, т.к.
    'открытые папки на компьютере тоже относятся к Internet Explorer.
    For Each oIE In oShellWindows
        If oIE.Application = sApplicationName Then
            'Помечаем, что программа Internet Explorer запущена.
            bFlag = True
            'Выходим из цикла.
            'При этом переменная oIE ссылается
            'на окно программы Internet Explorer.
            Exit For
        End If
    Next oIE
    
    'Если в переменной bFlag содержится False, то
    'выходим из кода.
    If bFlag = False Then
        MsgBox "IE не открыт!", vbCritical
        Exit Sub
    End If
    
    'Выводим в диалоговое окно Immediate Windows адрес страницы.
    Debug.Print oIE.LocationURL
    
End Sub
                        