Дана строка, содержащая текст на русском языке. Определить, сколько раз в ней встречается самое длинное слово. - Pascal ABC

program Project1;
 
const
  {Разделители слов.}
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  i, Cnt, Len, LenW, LenWMax : Integer;
  S : String;
begin
  repeat
    Writeln('Задайте текст:');
    Readln(S);
 
    {Решение.}
    Len := Length(S);
    Cnt := 0; {Количество слов с наибольшей длиной.}
    LenW := 0; {Длина очередного слова.}
    LenWMax := 0; {Наибольшая длина слова.}
    for i := 1 to Len do
      {Если символ не является разделителем, значит он принадлежит слову.}
      if not (S[i] in D) then begin
        {Учитываем текущий символ в длине слова.}
        Inc(LenW);
        {Отслеживаем конец слова.}
        if (i = Len) or (S[i + 1] in D) then begin
          {Если обнаружено слово, длина которого больше чем длины всех
          предыдущих слов, то начинаем счёт заново.}
          if LenW > LenWMax then begin
            LenWMax := LenW;
            Cnt := 1;
          end
          {Если обнаружено слово, длина которого равна наибольшей среди
          всех предыдущих слов, то наращиваем счётчик на 1.}
          else if LenW = LenWMax then
            Inc(Cnt);
          {Сброс длины слова.}
          LenW := 0;
        end;
      end;
 
    {Ответ.}
    if Cnt = 0 then
      Writeln('В тексте нет слов.')
    else begin
      Writeln('Наибольшая длина слова: ', LenWMax);
      Writeln('Количество слов с наибольшей длиной: ', Cnt);
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.