Найти сумму натуральных чисел от 1 до N ( N вводится с клавиатуры) - Assembler

Формулировка задачи:

data segment
data ends
code segment
start:
assume cs:code, ds:data
        mov     ax,     data
        mov     ds,     ax
 
    mov ah, 01  ;вводим первый символ и запоминаем его в bl
int 21h  
mov bl, al
 
    mov dl, bl
    mov dl, '0'
    mov ah, 02
cikl:   cmp dl, bl
    ja end_cikl
    int 21h
    inc dl
    jmp cikl
end_cikl:

Сделал чтобы вводились числа от 0 до какого-то числа, а как сложить их?

Решение задачи: «Найти сумму натуральных чисел от 1 до N ( N вводится с клавиатуры)»

textual
                            Листинг программы 
                        

                            _TEXT   segment word    public  'CODE'
        assume  cs:_TEXT, ds:_TEXT, ss:_TEXT
        org     100h
;---------------------------------------
; основная программа
;---------------------------------------
start:
        ;ввод N
        mov     ah,     09h
        lea     dx,     [PromptN]
        int     21h
        mov     ah,     0Ah
        lea     dx,     [KbdBuf]
        int     21h
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        lea     si,     [KbdBuf+1]
        lea     di,     [N]
        call    StrToInt
 
        ;вычисление суммы чисел от 1 до N
        mov     ax,     0
        mov     [Sum],  ax
        mov     cx,     [N]
        mov     ax,     1
        ForI:
                ;вычисление суммы
                add     [Sum],  ax
                inc     ax
        loop    ForI
 
        ;вывод результата (суммы) на экран
        mov     ah,     09h
        lea     dx,     [MsgSum]
        int     21h
        mov     ax,     [Sum]
        call    Show_AX
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        ;завершение программы
        int     20h
 
;---------------------------------------
; подпрограммы
;---------------------------------------
; преобразования строки в число
; на входе:
; ds:[si] - строка с числом
; ds:[di] - адрес числа
; на выходе
; ds:[di] - число
; CY - флаг переноса (при ошибке - установлен, иначе - сброшен)
StrToInt        proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    ds
        push    es
        push    si
 
        push    ds
        pop     es
 
        mov     cl, ds:[si]
        xor     ch, ch
 
        inc     si
 
        mov     bx, 10
        xor     ax, ax
 
        ;если в строке первый символ '-'
        ; - перейти к следующему
        ; - уменьшить количество рассматриваемых символов
        cmp     byte ptr [si], '-'
        jne     @@Loop
        inc     si
        dec     cx
@@Loop:
        mul     bx         ; умножаем ax на 10 ( dx:ax=ax*bx )
        mov     [di], ax   ; игнорируем старшее слово
        cmp     dx, 0      ; проверяем, результат на переполнение
        jnz     @@Error
 
        mov     al, [si]   ; Преобразуем следующий символ в число
        cmp     al, '0'
        jb      @@Error
        cmp     al, '9'
        ja      @@Error
        sub     al, '0'
        xor     ah, ah
        add     ax, [di]
        jc      @@Error    ; Если сумма больше 65535
        cmp     ax, 8000h
        ja      @@Error
        inc     si
 
        loop    @@Loop
 
        pop     si         ;проверка на знак
        push    si
        inc     si
        cmp     byte ptr [si], '-'
        jne     @@Check    ;если должно быть положительным
        neg     ax         ;если должно быть отрицательным
        jmp     @@StoreRes
@@Check:                   ;дополнительная проверка, когда при вводе положительного числа получили отрицательное
       or       ax, ax     ;
       js       @@Error
@@StoreRes:                ;сохранить результат
        mov     [di], ax
        clc
        pop     si
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
@@Error:
        xor     ax, ax
        mov     [di], ax
        stc
        pop     si
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
StrToInt        endp
 
; выводит число из регистра AX на экран
; входные данные:
; ax - число для отображения
Show_AX proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    di
 
        mov     cx, 10          ; cx - основание системы счисления
        xor     di, di          ; di - кол. цифр в числе
 
        ; если число в ax отрицательное, то
        ;1) напечатать '-'
        ;2) сделать ax положительным
        or      ax, ax
        jns     @@Conv
        push    ax
        mov     dx, '-'
        mov     ah, 2           ; ah - функция вывода символа на экран
        int     21h
        pop     ax
 
        neg     ax
 
@@Conv:
        xor     dx, dx
        div     cx              ; dl = num mod 10
        add     dl, '0'         ; перевод в символьный формат
        inc     di
        push    dx              ; складываем в стэк
        or      ax, ax
        jnz     @@Conv
        ; выводим из стэка на экран
@@Show:
        pop     dx              ; dl = очередной символ
        mov     ah, 2           ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@Show
 
        pop     di
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Show_AX endp
;---------------------------------------
; данные
;---------------------------------------
        CrLf    db      0Dh, 0Ah, '$'
        PromptN db      'Enter N: ', '$'
        MsgSum  db      'Summa: ', '$'
        KbdBuf  db      6, ?, 7 dup(?)
        N       dw      ?
        Sum     dw      ?
_TEXT   ends
 
        end     start
                        