Система шифрования Вижинера - VB

Формулировка задачи:

Система шифрования Вижинера Здравствуйте, помогите плиз написать код дешифратора на основе кода шифратора .Код шифратора я нагуглил . В программировании разбираюсь не очень..SOS

Private Sub cmdCodeVijiner_Click()
    'Описываем переменные
    Dim Alphabet As String 'Алфавит
    Dim Key As String 'Ключевое слово
    Dim EntranceText As String 'Шифруемый текст
    Dim TableVijiner() As String 'Таблица Вижинера
    Dim MarksInAlphabet As Integer 'Число знаков в алфавите
    Dim MarksInKey As Integer 'Число знаков в ключе
    Dim MarksInText As Integer 'Число знаков в тексте
    Dim CodeVijiner As String 'Шифрованный текст
    Dim i%, j%, k%, x%, Text$
    'Вводим алфавит
    Alphabet = "АБВГДЕЖЗИКЛМНОПРСТУФХЦЧШЩЬЫЭЮЯ"
    'или
    'Alphabet = "ABCDEFGHIJKLMNOPQRSTUVWXY"
    'Вычисляем количество знаков в алфавите
    MarksInAlphabet = CInt(Len(Alphabet))
    'Вводим ключ
    'и преобразуем прописные буквы в строчные
    Key = StrConv(txtKey, vbUpperCase)
    'Вычисляем количество знаков в ключе
    MarksInKey = CInt(Len(Key))
    'Проверям, есть ли подобные знаки в алфавите как в ключе
    For i = 1 To MarksInKey
        Text = Mid(Key, i, 1)
        k = InStr(Alphabet, Text)
        If k = 0 Then
            MsgBox "Знак '" & Text & "' не найден в алфавите. " _
                & "Введите другое ключевое слово.", , "Ошибка в ключе"
            Exit Sub
        End If
    Next i
    'Создаем таблицу Вижинера из алфавита
    ReDim TableVijiner(MarksInAlphabet, MarksInAlphabet)
    For i = 1 To MarksInAlphabet
        k = i
        For j = 1 To MarksInAlphabet
            If k > MarksInAlphabet Then k = k - MarksInAlphabet
            TableVijiner(i, j) = Mid(Alphabet, k, 1)
            k = k + 1
        Next j
    Next i
    'Вводим шифруемый текст
    'и преобразуем прописные буквы в строчные
    EntranceText = StrConv(txtEntrance, vbUpperCase)
    'Вычисляем количество знаков в тексте
    MarksInText = CInt(Len(EntranceText))
    'Проверям, есть ли подобные знаки в алфавите как в тексте
    For i = 1 To MarksInText
        Text = Mid(EntranceText, i, 1)
        If Text <> " " Then
            k = InStr(Alphabet, Text)
            If k = 0 Then
                MsgBox "Знак '" & Text & "' не найден в алфавите. " _
                    & "Измените шифруемый текст.", , "Ошибка в тексте"
                Exit Sub
            End If
        End If
    Next i
    'Шифруем текст
    x = 1
    For i = 1 To MarksInText
        Text = Mid(EntranceText, i, 1)
        If Text = " " Then
            CodeVijiner = CodeVijiner & " "
        Else
            If x > MarksInKey Then x = 1
            j = InStr(Alphabet, Mid(Key, x, 1))
            x = x + 1
            k = InStr(Alphabet, Text)
            CodeVijiner = CodeVijiner & TableVijiner(k, j)
        End If
    Next i
    'Выводим таблицу Вижинера
    txtTableVijiner.Text = ""
    For i = 1 To MarksInAlphabet
        For j = 1 To MarksInAlphabet
            txtTableVijiner.Text = txtTableVijiner.Text & TableVijiner(i, j)
        Next j
        txtTableVijiner.Text = txtTableVijiner.Text & vbCrLf
    Next i
    'Выводим шифрованный текст
    txtCodeVijiner.Text = CodeVijiner
End Sub

Решение задачи: «Система шифрования Вижинера»

textual
                            Листинг программы 
                        

                            Dim n%
Dim table(255)
 
' алфавит русс.
Private Sub Command1_Click()
Call Ru(223, 184)
MsgBox "ключ:   " & String(28, " ") & "авс" & vbLf & _
       "открытый текст:            " & kodek(0, kodek(1, "открытый текст", "авс"), "авс") & vbLf & _
       "зашифрованный текст: " & kodek(1, "открытый текст", "авс")
End Sub
 
'.....................................
'функция возвращает строку : если = 1(True), - то зашифрованный,  если=0(False), - то расшифрованную (восстановленную)
Function kodek(kd As Boolean, txt As String, Key_txt As String) As String
   d = Len(txt)
   kodek = ""
      For i = 1 To d
          i1 = IIf(i Mod Len(Key_txt) = 0, Len(Key_txt), i Mod Len(Key_txt))
          s = Mid(txt, i, 1)
          s1 = Mid(Key_txt, i1, 1)
              If Asc(s) = 10 Or Asc(s) = 13 Or Asc(s) = 9 Then
                 kodek = kodek & s
              Else
                 For p = 0 To n
                     If s = table(p) Then iword = p
                     If s1 = table(p) Then ikey = p
                 Next p
                 ind = IIf(kd, (iword + ikey) Mod n, (iword - ikey + n) Mod n)
                 kodek = kodek + table(ind)
              End If
       Next i
End Function
 
'..............................................
Sub Ru(a As Integer, e As Integer)
pp = 1
 For i = 0 To 32
  If i = 6 Then
     table(6) = Chr(e)
     pp = 0
  Else
      table(i) = Chr(i + a + pp)
  End If
 Next i
n = 34
table(33) = Chr(32)
End Sub
                        