Удаление файла в корзину и его восстановление - VB

Формулировка задачи:

здраствуйте помогите пожайлуста как в basice удалить какой то файл в корзину и опять востановить

Решение задачи: «Удаление файла в корзину и его восстановление»

textual
                            Листинг программы 
                        

                            Public Type SHFILEOPSTRUCT
    hwnd As Long
    wFunc As Long
    pFrom As Long
    pTo As Long
    fFlags As Integer
    fAnyOperationsAborted As Long
    hNameMappings As Long
    lpszProgressTitle As Long
End Type
 
Public Declare Function SHFileOperation Lib "Shell32.dll" Alias "SHFileOperationW" (lpFileOp As SHFILEOPSTRUCT) As Long
 
' Удаление файла в корзину (возвращает 0 в случае успеха)
Public Function SendFileToRecycleBin(ByVal FileName As String, Optional Confirm As Boolean = False, Optional Silent As Boolean = True) As Long
    On Error GoTo ErrorHandler
    Const FO_DELETE             As Long = &H3
    Const FOF_ALLOWUNDO         As Long = &H40
    Const FOF_NOCONFIRMATION    As Long = &H10
    Const FOF_SILENT            As Long = &H4
    Dim FileOp As SHFILEOPSTRUCT
    
    FileName = FileName & Chr(0)
    
    With FileOp
        .wFunc = FO_DELETE
        .pFrom = StrPtr(FileName)
        .fFlags = FOF_ALLOWUNDO
        If Not Confirm Then .fFlags = .fFlags Or FOF_NOCONFIRMATION
        If Silent Then .fFlags = .fFlags Or FOF_SILENT
    End With
    SendFileToRecycleBin = SHFileOperation(FileOp)
    Exit Function
ErrorHandler:
    debug.? Now, Err, "Parser.SendFileToRecycleBin"
End Function
                        