К последнему элементу второго массива прибавить последний элемент первого, к предпоследнему - прибавить предпоследний - Assembler

Узнай цену своей работы

Формулировка задачи:

Объявите в программе два массива 16-битных целых со знаком. Количество элементов массивов должно быть одинаковым и храниться в 8-битной переменной без знака. Требуется к последнему элементу второму массива прибавить последний элемент первого, к предпоследнему — прибавить предпоследний элемент и т.д.

Решение задачи: «К последнему элементу второго массива прибавить последний элемент первого, к предпоследнему - прибавить предпоследний»

textual
Листинг программы
.model small
 
.stack 100h
 
.data
        CrLf            db      0Dh, 0Ah, '$'
        msgFirstArray   db      0Dh, 0Ah, ' - 1st array:', 0Dh, 0Ah, '$'
        msgSecondArray  db      0Dh, 0Ah, ' - 2nd array:', 0Dh, 0Ah, '$'
        msgInitial      db      'Initial:', '$'
        msgResult       db      0Dh, 0Ah, 'Result:', '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
 
        A               dw      -1, -2, -3, -4, -5, -6, -7, -8, -9, -10
        B               dw      10, 20, 30, 40, 50, 60, 70, 80, 90, 100
        N               db      10
.code
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
 
        ;вывод исходных данных
        mov     ah,     09h
        lea     dx,     [msgInitial]
        int     21h
        call    ShowArrays
        ;обработка
        lea     si,     [A]
        lea     di,     [B]
        xor     bx,     bx
        mov     bl,     [N]
        dec     bx
        shl     bx,     1
        @@for:
                mov     ax,     [si+bx]
                add     [di+bx],        ax
                sub     bx,     2
        jnb     @@for
        ;вывод результата
        mov     ah,     09h
        lea     dx,     [msgResult]
        int     21h
        call    ShowArrays
 
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
 
        mov     ax,     4C00h
        int     21h
main    endp
 
;Вывод массива слов (word)
;cx - количество выводимых элементов
;ds:dx - адрес массива слов
ShowArray       proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        jcxz    @@Exit          ;если массив пустой - завершить
 
        mov     si,     1       ;индекс элемента массива
        mov     di,     dx      ;адрес текущего элемента массива
        @@ForI:
                mov     ax,     [di]
                call    Show_AX
                mov     ah,     02h
                mov     dl,     ' '
                int     21h
                ;переход к следующему элементу
                inc     si
                add     di,     2
        loop    @@ForI
@@Exit:
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
ShowArray       endp
 
; выводит знаковое 16-разрядное число из регистра AX на экран
; с выравниванием на 5 позиций по правому краю
; входные данные:
; ax - число для отображения
Show_AX proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     cx,     10      ;основание системы счисления
        xor     di,     di      ; di - кол. цифр в числе
        xor     si,     si      ; si - признак отрицательного числа
        ; если число в ax отрицательное, то
        ;1) напечатать (запомнить в стеке) символ '-'
        ;2) сделать ax положительным
        or      ax,     ax
        jns     @@Conv
        mov     si,     1
 
        neg     ax
 
@@Conv:
        xor     dx,     dx
        div     cx              ; dl = num mod 10
        add     dl,     '0'     ; перевод в символьный формат
        inc     di
        push    dx              ; складываем в стек
        or      ax,     ax
        jnz     @@Conv
        ;если число отрицательное - помещаем символ "-" в строку
        or      si,     si
        jz      @@Positive
        mov     dx,     '-'
        push    dx
        inc     di
@@Positive:
        ; выводим из стека на экран
        ; - сначала пробелы для выравнивания по правому краю
        mov     cx,     5
        sub     cx,     di
        mov     ah,     02h
        mov     dl,     ' '
@@LeftPad:
        int     21h
        loop    @@LeftPad
        ;сохранённые символы цифр
@@Show:
        pop     dx              ; dl = очередной выводимый символ
        mov     ah,     2       ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@Show
 
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Show_AX endp
 
ShowArrays      proc
        mov     ah,     09h
        lea     dx,     [msgFirstArray]
        int     21h
        lea     dx,     [A]
        xor     cx,     cx
        mov     cl,     [N]
        call    ShowArray
        mov     ah,     09h
        lea     dx,     [msgSecondArray]
        int     21h
        lea     dx,     [B]
        xor     cx,     cx
        mov     cl,     [N]
        call    ShowArray
        ret
ShowArrays      endp
 
end     main

Оцени полезность:

11   голосов , оценка 4.182 из 5
Похожие ответы