Как организовать сохранение преобразованной триады символов и вывести полученное значение на экран? - Assembler

.MODEL  Small
 
.DATA
 
KeyBuf  db      7, 0, 7 dup(0)      ;max,len,string,CR(0dh)
CR_LF   db      0Dh, 0Ah, '$'
 
Prompt  db      'Введите число (-32768..+32767): ', '$'
Res10   db      'Введено число (десятичное    ): ', '$'
Res08   db      'Введено число (восьмеричное  ): ', '$'
Error01 db      'Ошибка ввода числа',0Dh, 0Ah, '$'
ExitMsg db      'Для завершения нажмите Esc', '$'
 
Numer   dw      -123
 
.CODE
 
; выводит число в регистре AX на экран
; входные данные:
; cx - система счисления (не больше 10)
; ax - число для отображения
Show_ax PROC
;        mov     cx, 10
        xor     di, di          ; di - кол. цифр в числе
 
        ; если число в ax отрицательное, то
        ;1) напечатать '-'
        ;2) сделать ax положительным
        or      ax, ax
        jns     @@Conv
        push    ax
        mov     dx, '-'
        mov     ah, 2           ; ah - функция вывода символа на экран
        int     21h
        pop     ax
 
        neg     ax
 
@@Conv:
        xor     dx, dx
        div     cx              ; dl = num mod 10
        add     dl, '0'         ; перевод в символьный формат
        inc     di
        push    dx              ; складываем в стэк
        or      ax, ax
        jnz     @@conv
        ; выводим из стэка на экран
@@Show:
        pop     dx              ; dl = очередной символ
        mov     ah, 2           ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@show
        ret
Show_ax ENDP
 
Main    PROC    FAR
        mov     ax, @DATA
        mov     ds, ax
        mov     es, ax
 
@@NoError:
        ; в десятичном представлении
        lea     dx, Res10
        mov     ah,09h
        int     21h
 
        mov     ax, Numer
        mov     cx, 10
        call    Show_ax
 
        lea     dx, CR_LF
        mov     ah,09h
        int     21h
 
        ; в восьмеричном представлении
        lea     dx, Res08
        mov     ah,09h
        int     21h
 
        mov     ax, Numer
        mov     cx, 8
        call    Show_ax
 
        lea     dx, CR_LF
        mov     ah,09h
        int     21h
 
        ; выход
@@Exit:
        lea     dx, ExitMsg
        mov     ah,09h
        int     21h
 
        ; ожидание нажатия клавиши Esc
@@WaitForEsc:
        mov     ah,07h        ; ожидаем нажатие любой клавиши
        int     21h
 
        cmp     al, 1Bh       ; 1Bh - код клавиши Esc
        jnz     @@WaitForEsc  ; если это не Esc, то повторить
 
        mov     ax,4c00h
        int     21h
Main    ENDP
 
.STACK  100h
 
        END     Main