Программа на графику - Assembler

org 100h
start:
mov ax,13h
int 10h
 
xor ax,ax
int 33h
mov ax,1
int 33h
 
mov ax,12
mov cx,3
mov dx,handler
int 33h
 
push 0A000h
pop  es
 
xor ax,ax
int 16h
ret
 
handler:
  mov  ax,2
  int  33h            ;выключаем курсор мыши
 
  shr  cx,1
  push dx
  push cx             ;передаём координаты курсора в качестве параметров функции line
 
  and  bx,1
  jz @f
  cmp  bl,[z]             ;если нажата левая кнопка мыши копируем содержимое экрана в буфер
  jz @f
    mov  [y],dx
    mov  [x],cx
 
    mov  cx,320*200/2
    push es
    push ds
    pop  es
    pop  ds
    mov  di,buffer
    xor  si,si
    rep  movsw
    push es
    push ds
    pop  es
    pop  ds
  @@:
  mov  [z],bl
 
  xor  di,di
  mov  si,buffer
  mov  cx,320*200/2
  rep  movsw              ;копируем буфер на экран
 
  call line           ;рисуем линию из точки (x,y) в точку, на которую указывает курсор
 
  mov  ax,1
  int  33h            ;включаем курсор мыши
retf
 
floodfill:
 
line:
  push bp
  mov  bp,sp
  imul di,[y],320
  add  di,[x]
 
  mov  ax,[ss:bp+4]
  sub  ax,[x]
  sbb  bx,bx
  mov  dx,[ss:bp+6]
  sub  dx,[y]
  sbb  cx,cx
 
  mov  si,ax
  or   si,dx
  je   quit
 
  xor  ax,bx
  sub  ax,bx
  xor  dx,cx
  sub  dx,cx
 
  or   bx,1
  mov  si,cx
  xor  cx,320
  sub  cx,si
 
  cmp  ax,dx
  ja a
      xchg ax,dx
      xchg bx,cx
  a:
 
  mov  si,ax
  mov  bp,ax
  b:mov byte[es:di],2
    sub si,dx
    jnl next
      add si,ax
      add di,cx
    next:
    add di,bx
    dec bp
  jne b
 
  quit:
  mov byte[es:di],2
  pop bp
ret 4
 
x      dw 160
y      dw 100
z      db 0
buffer rb 0