Сжать текст, оставив между словами по одному пробелу - Assembler

; fasm-code..
; Удаляет лишние пробелы
;--------------------------
org  100h
jmp  start
 
szSrc    db  'We have a string, who haves a     maaany     spaces',13,10,'$'
len      =   ($ - szSrc)-3
 
start:
   mov   ah,9           ; исходная строка
   mov   dx,szSrc
   int   21h
;=======================================================//
   mov   cx,len         ; длина строки
   mov   si,szSrc       ; адрес для чтения
   mov   di,si          ;   ..и записи.
   xor   ax,ax          ; АХ := 0
cycle:                  ;
   lodsb                ; считать символ
   cmp   al,' '         ; пробел?
   jne   miss           ; нет - пропускаем
   cmp   ax,'  '        ; да - тест с предыдущим
   je    next           ; 2 пробела - пропускаем
miss:                   ;
   stosb                ; перезапись символа
next:                   ;
   xchg  ah,al          ; запомним текущий символ
   loop  cycle          ;
 
   mov   al,'$'         ; вставляем маркер конца стоки
   stosb                ;
;=======================================================//
   mov   ah,9           ; изменённая строка
   mov   dx,szSrc       ;
   int   21h            ;
 
   xor   ax,ax          ;
   int   16h            ;
   int   20h            ;