Выполнить циклический сдвиг массива на К чисел влево - Assembler

; Выполнить циклический сдвиг массива на k-чисел влево
;fasm code....
org  100h
jmp  start
 
mess0   db   13,10,' String: $'
mess1   db   13,10,'  Shift: $'
mess2   db   13,10,' Result: $'
buff    db   80 dup('$')     ; буфер для ввода
len dw   0           ; длина строки
 
start:  mov   dx,mess0       ;
    call  message        ;
    xor   cx,cx      ; обнуляем длину
    mov   di,buff        ; адрес приёмника
    mov   ah,1       ; ввод с эхом
input:  int   21h        ;
    cmp   al,13      ; Enter - закончить ввод
    je    begin      ;
    stosb            ; сохраняем символ в буфере
    inc   cx         ; считаем длину строки
    jmp   input      ;
 
begin:  mov   [len],cx       ; запомним её..
    mov   dx,mess1       ;
    call  message        ;
    mov   ah,1       ; вводим(k) - значение сдвига
    int   21h        ; (здесь можешь добавить фильтр чисел)
    and   ax,0fh         ;
    push  ax         ; запомним..
 
    mov   dx,mess2       ;
    call  message        ;
    pop   bx         ; ВХ = кол-во сдвигов (счётчик цикла)
worm:   mov   si,buff        ; источник,
    mov   di,si      ;    ..он-же приёмник
    lodsb            ; берём первый элемент
    push  ax         ; запоминаем его в стеке
    mov   cx,[len]       ; длина строки для MOVSB
    dec   cx         ;    ..без первого элемента
    rep   movsb      ; смещаем всю строку влево!
    pop   ax         ; снимаем первый элемент
    stosb            ; записываем его последним символом
    dec   bx         ; уменьшаем кол-во сдвигов
    jnz   worm       ; ВХ нуль? Нет - на повтор..
 
    mov   dx,buff        ; выводим сдвинутую строку на экран!
    call  message        ;
 
exit:   xor   ax,ax      ; ждём любую клавишу..
    int   16h        ;
    int   20h        ; выход!
;---------------------------------------------------------------------
message:             ; вывод строки средствами DOS
    mov   ah,9       ;
    int   21h        ;
    ret          ;