Из группы файлов найти тот, в котором наибольшее количество строк - Free Pascal

uses dos;
 
const
  path = 'd:\test\';
 
function getSum(n : longint) : Integer;
begin
  GetSum := 0;
  while n > 0 do
  begin
    Inc(GetSum, n mod 10);
    n := n div 10;
  end;
end;
 
var
  MaxLines : integer;
  MaxName : string;
 
procedure CheckFile(fn : string);
var
  t : text;
  s : string;
  value : longint;
  code, lines : integer;
 
  has_27 : boolean;
begin
  {$i-}
  assign(t, fn);
  reset(t);
  {$i+}
  if ioresult <> 0 then
  begin
    writeln('Ошибка при открытии файла ', fn);
    exit;
  end;
 
  lines := 0; has_27 := false;
  while not eof(t) do
  begin
    readln(t, s); inc(lines);
    val(s, value, code);
    if code = 0 then { <--- Все в порядке, целое число }
    begin
      has_27 := has_27 or (GetSum(value) = 27);
    end;
  end;
 
 
  if (MaxLines < lines) and has_27 then
  begin
    MaxLines := lines;
    MaxName := fn;
  end;
end;
 
var
  Info : SearchRec;
 
begin
  MaxLines := 0;
  MaxName := '';
 
  FindFirst(path + '*.txt', AnyFile, Info);
  while DosError = 0 do
  begin
    CheckFile(path + Info.name);
    FindNext(info)
  end;
  FindClose(Info);
 
  if MaxLines > 0 then
    Writeln ('Поиск окончен. ', MaxName, ' содержит ', MaxLines,' строк')
  else
    Writeln ('Либо нет txt-файлов, либо ни один из них не содержит числа с суммой цифр = 27');
end.