Ошибка: Нельзя изменять значение переменной цикла внутри этого цикла - Pascal ABC

Формулировка задачи:

при запуске в цикле while в строке x:=x div 10; выдает ошибку "Нельзя изменять значение переменной цикла внутри этого цикла", объясните пожалуйста, и по возможности исправьте..... буду оч благодарна. вот текст программы

{Подсчитать количество четных натуральных чисел, принадлежащих интервалу
 [ a , b ), у которых количество четных цифр больше количества нечетных цифр.}
 
 var a,b,d,x,y,j,k : integer; {j - количество четных цифр, k - нечетных, d - 
                             количество натуральных чисел}
 BEGIN
    writeln('Введите число а > ');
    readln(a);
    writeln('Введите число b > ');
    readln(b);
    j:=0;
    k:=0;
    d:=0;
    if ((a<0) or (b<0) or (a>b)) then  
       writeln('Числа a и b должны быть натуральными, причем a<b!')
       else begin
             for x:=a to b-1 do begin
                if (x mod 2 = 0) then begin
                      while x>0 do begin
                            y:=x mod 10;
                            if (y mod 2 =0) then
                               j:=J+1
                               else k:=k+1;
                            x:=x div 10;
                      end;
                end; 
                if j>k then 
                   d:=d+1;
             end; 
             writeln('Количество четных натуральных чисел, принадлежащих интервалу');
             writeln('[',a,';',b,'), у которых количество четных цифр больше количества');
             writeln('нечетных, равно ', d, ' ');
       end;
END.

Решение задачи: «Ошибка: Нельзя изменять значение переменной цикла внутри этого цикла»

Листинг программы

uses crt;
 var a,b,d,x,x1,y,j,k : integer; {j - количество четных цифр, k - нечетных, d -
                             количество натуральных чисел}
 BEGIN
    writeln('Введите число а > ');
    readln(a);
    writeln('Введите число b > ');
    readln(b);
    if ((a<0) or (a>b)) then
    writeln('Числа a и b должны быть натуральными, причем a<b!')
    else
     begin
      d:=0;
      for x:=a to b-1 do
      if (x mod 2 = 0) then
       begin
        x1:=x;//нельзя издеваться над счетчиком цикла...
        j:=0;
        k:=0;
        while x1>0 do
         begin
          y:=x1 mod 10;
          if y mod 2 =0 then j:=J+1
          else k:=k+1;
          x1:=x1 div 10;
         end;
        if j>k then d:=d+1;
       end;
      writeln('Количество четных натуральных чисел, принадлежащих интервалу');
      writeln('[',a,';',b,'), у которых количество четных цифр больше количества');
      writeln('нечетных, равно ', d, ' ');
    end;
END.

Объяснение кода листинга программы

Объявление переменных: a, b, d, x, x1, y, j, k (указаны в коде)
Ввод чисел a и b с помощью функции readln
Проверка на корректность введенных чисел: a < 0 или a > b. Если условие не выполняется, выводится сообщение об ошибке.
Инициализация переменной d = 0. Переменная используется для подсчета количества натуральных чисел с четным количеством цифр.
Запуск цикла for, который проходит по всем числам в заданном интервале (от a до b-1).
Внутри цикла проверяется, является ли текущее число четным с помощью оператора mod 2 = 0.
Если число четное, то начинается новый цикл while, который считает количество четных цифр в числе.
Внутри цикла while происходит проверка каждой цифры числа с помощью оператора mod 10. Если цифра четная, то увеличивается значение переменной j.
После окончания цикла while, проверяется, какое количество четных цифр больше: j или k. Если j > k, то увеличивается значение переменной d.
По завершении всех циклов выводится сообщение с количеством натуральных чисел в интервале [a; b], у которых количество четных цифр больше количества нечетных. Значение переменной d выводится на экран.