Найти номер наибольшего нечётного элемента массива m на n - Pascal

const mm = 6; {максимальные размеры массива}
      mn = 6;
var a: array[1..mm, 1..mn] of integer;
    i, j, m, n, mi, mj: integer;
    f: boolean;
begin
  {ввод размера массива с проверкой}
  repeat
    write('m в диапазоне 1..', mm, ';  m = ');
    readln(m)
  until m in [1..mm];
  repeat
    write('n в диапазоне 1..', mn, ';  n = ');
    readln(n)
  until n in [1..mn];
  {ввод элементов массива}
  writeln('Введите элементы массива:');
  for i := 1 to m do
    for j := 1 to n do
      begin
        write('A[', i, ', ', j, '] = ');
        readln(a[i, j])
      end;
  {вывод массива}
  writeln('Исходный массив');
  for i := 1 to m do
    begin
      for j := 1 to n do write(a[i, j]:12);
      writeln
    end;
  {поиск номеров наибольшего нечётного элемента массива}
  f := false; {флаг факта находки нужного элемента, пока не нашли, поэтому false}
  for i := 1 to m do
    for j := 1 to n do
      if odd(a[i, j]) {если элемент нечётный,}
        then if not f or (a[i, j] > a[mi, mj]) {то, если элемент ещё не был найден или элемент больше максимального,}
          then begin {то}
            mi := i; {запоминаем номера максимального элемента}
            mj := j;
            f := true {помечаем, что максимальный элемент найден}
          end;
  {печатаем результат}
  if f
    then write('Максимальный элемент = ', a[mi, mj], '; его номера: по вертикали ', mi, ', по горизонтали ', mj)
    else write('В массива нет нечётных элементов');
  readln
end.