Включить после каждого элемента списка с максимальным значением его копию - Pascal

const
  maxRandomValue = 10;
  
type
  tList = ^rList;
  rList = record
    a : Integer;
    n : tList;
  end;
 
function CreateRandomList(n : Integer) : tList;
var
  Cur : tList;
begin
  if n <= 0 then
    CreateRandomList := nil
  else
    begin
      New(Cur);
      Cur^.a := Random(maxRandomValue);
      CreateRandomList := Cur;
      while n > 1 do
        begin
          New(Cur^.n);
          Cur := Cur^.n;
          Cur^.a := Random(maxRandomValue);
          Dec(n);
        end;
      Cur^.n := nil;
    end;
end;
 
function MaxList(a : tList) : Integer;
var
  m : Integer;
begin
  MaxList := 0;
  if a = nil then Exit;
  
  m := a^.a;
  while a <> nil do
    begin
      if a^.a > m then m := a^.a;
      a := a^.n;
    end;
    
  MaxList := m;
end;
 
procedure ModificationList(m : Integer; var a : tList);
var
  Cur, Next : tList;
begin
  Cur := a;
  while Cur <> nil do
    if Cur^.a = m then
      begin
        Next := Cur^.n;
        New(Cur^.n);
        Cur := Cur^.n;
        Cur^.a := m;
        Cur^.n := Next;
        Cur := Next;
      end
    else
      Cur := Cur^.n;
end;
  
procedure OutList(a : tList);
var
  Cur : tList;
begin
  if a = nil then WriteLn('<список пуст>')
  else
    begin
      Cur := a;
      while Cur <> nil do
        begin
          Write(#32, Cur^.a);
          Cur := Cur^.n;
        end;
      WriteLn;
    end;
end;
 
var
  n, m : Integer;
  a : tList;
begin
  Randomize;
  Write('Число элементов списка: n = '); ReadLn(n);
  a := CreateRandomList(n);
  Write('Список a:'); OutList(a);
  m := MaxList(a); WriteLn('Максимальное значение = ', m);
  ModificationList(m, a);
  Write('Список a:'); OutList(a);
end.