Найти корни квадратного уравнения - Turbo Pascal (31549)

uses crt;
type tlinur=object{линейное уравнение}
     a0,a1:real;{свободный член и коэффициент при х}
     k:integer; {количество корней - минус 1, 0, 1}
     x1:real; {значение корня}
     procedure init (a,b:real); {инициализация}
     procedure linur; {решение линейного уравнения}
     procedure print; {вывод решения на экран}
     end;
tkvur=object(tlinur){квадратное уравнение}
      a2,x2:real; {коэффициент при квадрате неизвестного и второй корень}
      procedure init(a,b,c:real); {инициализация}
      procedure kvur; {решение квадратного уравнения}
      procedure print2; {вывод решения на экран}
      end;
procedure tlinur.init(a,b:real);
begin
a1:=a;
a0:=b
end;
procedure tlinur.linur;
begin
if a1<>0 then
 begin
  k:=1;
  x1:=-a0/a1
 end
else if a0=0 then k:=-1
else k:=0
end;
procedure tlinur.print;
begin
case k of
-1:writeln('любое значение');
0:writeln('решений нет');
1: writeln('один корень=',x1:0:2)
end
end;
procedure tkvur.init(a,b,c:real);
begin
inherited init(a,b); {коэффициент при х и свободный член}
a2:=c;{коэффициент при x^2}
end;
procedure tkvur.kvur;
var d:real;
begin
if a2<>0 then
 begin
  d:=(sqr(a1)-4*a2*a0);
  if d>=0 then
   begin
    x1:=(-a1+sqrt(d))/(2*a2);
    x2:=(-a1-sqrt(d))/(2*a2);
    k:=2
   end
  else k:=0
 end
else linur
end;
procedure tkvur.print2;
begin
case k of
-1..1:print;
2:writeln('два корня x1=',x1:0:2,'  x2=',x2:0:2)
end
end;
var u:tkvur;
    a,b,c:real;
begin
clrscr;
writeln('Введите коэффициенты уравнения a,b,c (a и b одновременно не равны 0)');
readln(a,b,c);
u.init(a,b,c);
u.kvur;
u.print2;
readln
end.