Как поменять столбец, из которого необходимо взять значения? - VBA

   b = MyR.Offset(0, n).Resize(n, 1)  'матрица (вектор) свободных членов

Option Explicit
 
Public a As Variant
Public b As Variant
Public x As Variant
 
Sub Main()
    Dim MyR As Range
    Dim n As Integer, i As Integer
    Dim RowB As Integer, ColE As Integer
    
    Set MyR = Selection
    With MyR
        If .Columns.Count - 1 <> .Rows.Count Then
            MsgBox "Вы должны были выделить область n строк и n+1 колонку!", vbCritical
            Exit Sub
        End If
        n = .Rows.Count  'Определили число строк матрицы
        If n < 2 Then
            MsgBox "Вы должны были выделять область, а не ячейку!", vbCritical
            Exit Sub
        End If
        RowB = .Rows(1).Row
        ColE = .Columns(1).Column + n
    End With
    'Одна из фишек VBA - одной командой инициализируем массивы
    a = MyR.Resize(n, n)                'матрица системы
    b = MyR.Offset(0, n).Resize(n, 1) 'матрица (вектор) свободных членов
    ReDim x(1 To n)
    Forwards n  'Прямой ход
    Backwards n 'Обратный ход
    For i = 1 To n
        Cells(RowB + i - 1, ColE + 1).Value = x(i)
    Next i
    MsgBox "Решение помещено правее свободных членов", vbInformation
    Cells(RowB + n, 1).Select
End Sub
 
Sub Forwards(n As Integer)
    Dim c As Double
    Dim i As Integer, m As Integer, j As Integer, k As Integer, l As Integer
    For i = 1 To n - 1
        l = i
        For m = i + 1 To n
            If Abs(a(m, i)) > Abs(a(l, i)) Then l = m
        Next m
        If l <> i Then
            Swap i, l, n
        End If
        For k = i + 1 To n
            c = a(k, i) / a(i, i)
            a(k, i) = 0
            For j = i + 1 To n
                a(k, j) = a(k, j) - c * a(i, j)
            Next j
            b(k, 1) = b(k, 1) - c * b(i, 1)
        Next k
    Next i
End Sub
 
Sub Swap(i1 As Integer, i2 As Integer, n As Integer)
    'Обменивает местами элементы в строках i1 и i2)
    Dim t As Double
    Dim j As Integer
    For j = 1 To n
        t = a(i1, j)
        a(i1, j) = a(i2, j)
        a(i2, j) = t
    Next j
    t = b(i1, 1)
    b(i1, 1) = b(i2, 1)
    b(i2, 1) = t
End Sub
 
Sub Backwards(n As Integer)
    Dim i As Integer, j As Integer
    Dim t As Double
    x(n) = b(n, 1) / a(n, n)
    For i = n - 1 To 1 Step -1
        t = 0
        For j = i + 1 To n
            t = t + a(i, j) * x(j)
        Next j
        x(i) = (b(i, 1) - t) / a(i, i)
    Next i
End Sub