Интерфейс не поддерживается (ошибка) - VB

Формулировка задачи:

Здравствуйте. Работаю в Arena. Делал для проекта формы на ВБ, не добавлялся компонент "CommonDialog" с ошибкой "интерфейс не поддерживается" т.е на форму не добавлялся. Добавил на другом компе,теперь при попытке запустить проект на моем пк вылетает ошибка интерфейс не поддерживается и out of memory. Что делать?

Решение задачи: «Интерфейс не поддерживается (ошибка)»

textual
                            Листинг программы 
                        

                            Option Explicit
 
Private Type OPENFILENAME
    lStructSize         As Long
    hwndOwner           As Long
    hInstance           As Long
    lpstrFilter         As Long
    lpstrCustomFilter   As Long
    nMaxCustFilter      As Long
    nFilterIndex        As Long
    lpstrFile           As Long
    nMaxFile            As Long
    lpstrFileTitle      As Long
    nMaxFileTitle       As Long
    lpstrInitialDir     As Long
    lpstrTitle          As Long
    flags               As Long
    nFileOffset         As Integer
    nFileExtension      As Integer
    lpstrDefExt         As Long
    lCustData           As Long
    lpfnHook            As Long
    lpTemplateName      As Long
End Type
 
Private Declare Function GetSaveFileName Lib "comdlg32.dll" Alias "GetSaveFileNameW" (pOpenfilename As OPENFILENAME) As Long
 
Private Const OFN_OVERWRITEPROMPT = &H2
Private Const OFN_EXPLORER = &H80000
 
Private Function GetSaveFile(ByVal hwnd As Long) As String
    Dim ofn As OPENFILENAME, Out As String, i As Long
    
    ofn.nMaxFile = 260
    ofn.flags = OFN_OVERWRITEPROMPT Or OFN_EXPLORER
    Out = String(260, vbNullChar)
    ofn.hwndOwner = hwnd
    ofn.lpstrTitle = StrPtr("Г‘Г®ГµГ°Г*Г*ГЁГІГј")
    ofn.lpstrFile = StrPtr(Out)
    ofn.lStructSize = Len(ofn)
    ofn.lpstrFilter = StrPtr("Г‚Г±ГҐ ГґГ*Г©Г«Г»" & vbNullChar & "*.*")
    ofn.lpstrDefExt = 0
    If GetSaveFileName(ofn) Then
        i = InStr(1, Out, vbNullChar, vbBinaryCompare)
        If i Then GetSaveFile = Left$(Out, i - 1)
    End If
End Function
 
Private Sub Form_Load()
    MsgBox GetSaveFile(Me.hwnd)
End Sub
                        