Как открыть, запустить файл из VB&

Формулировка задачи:

Это наверное просто, но у меня не получается..., хотелось бы как-то из кода открыть файл, чтобы запустилась соответствующая, или конкретная-указанная программа... В частности мне надо чтобы открывалась страница в Explorer... Буду очень признательна за помостч...

Решение задачи: «Как открыть, запустить файл из VB&»

textual
                            Листинг программы 
                        

                            ' ОТКРЫТИЕ ФАЙЛА ПО РАСШИРЕНИЮ:
' ДЕКЛАРАЦИЯ: открытие файла по расширению
  Private Declare Function ShellExecuteA Lib "shell32.dll" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
' ФУНКЦИЯ: открытие файла по расширению
' lngWnd - дикриптор окна (нужно указать Me.hWnd)
' strFile - имя файла (полный путь к файлу)
' Возвращает признак нормального завершения
Public Function OpenFileExt(lngWnd As Long, strFile As String) As Boolean
  ' Переменные
    Dim intCursor As Integer ' курсор мыши
  ' Код
    ' сохранение курсора мыши
    intCursor = Screen.MousePointer
    ' курсор мыши - песочные часы
    Screen.MousePointer = vbHourglass
    ' запуск перехватчика
    On Error GoTo SubError
    ' открытие файла по расширению
    ShellExecuteA lngWnd, "open", strFile, "", "", 1
    ' установка признака нормального завершения
    OpenFileExt = True
    ' обход перехватчика
    GoTo Continue
SubError:
    ' снятие признака нормального завершения
    OpenFileExt = False
    ' выход из перехватчика
    Resume Continue
Continue:
    ' остановка перехватчика
    On Error GoTo 0
    ' восстановление курсора мыши
    Screen.MousePointer = intCursor
End Function
                        