Как узнать инициализирован ли массив? - VB

Формулировка задачи:

Постоянно забываю, как это правильно делать.Здесь прочитал такой способ:

Option Explicit
 
'SAFEARRAY** (указатель на указатель на SAFEARRAY, для всех типов кроме String)
Private Declare Function ArrPtr Lib "msvbvm60" Alias "VarPtr" (Arr() As Any) As Long
'Аналог RtlMoveMemory на 4 байта
Private Declare Function GetMem4 Lib "msvbvm60" (ByVal pSrc As Long, ByVal pDst As Long) As Long
'Копирование участка памяти (что не очевидно из названия функции :) )
Private Declare Sub RtlMoveMemory Lib "kernel32" (ByVal Destination As Any, ByVal Source As Any, ByVal Length As Long)
 
Private StringArray() As String
Private LongArray() As Long
Private DoubleArray() As Double
 
Private Sub Form_Load()
    'ReDim LongArray(255)
    'ReDim StringArray(255)
    MsgBox ArrayExists(StrArrPtr(StringArray))
    MsgBox ArrayExists(ArrPtr(LongArray))
    MsgBox ArrayExists(ArrPtr(DoubleArray))
End Sub
 
'SAFEARRAY* (указатель на SAFEARRAY)
Private Function ArrayExists(ByVal ArrPt As Long) As Boolean
    Dim ret As Long
    GetMem4 ArrPt, VarPtr(ret)
    ArrayExists = ret
End Function
 
'SAFEARRAY** (для массива типа String)
Private Function StrArrPtr(ByRef Arr() As String, Optional ByVal IgnoreMe As Long = 0) As Long
    GetMem4 VarPtr(IgnoreMe) - 4, VarPtr(StrArrPtr)
End Function

Но что-то мне совсем не нравится как определяется адрес SafeArray типа String. Поэтому пользуюсь этим способом:

Option Explicit
 
Private Declare Function SafeArrayGetDim Lib "oleaut32.dll" (psa() As Any) As Long
 
Private StringArray() As String
Private LongArray() As Long
Private DoubleArray() As Double
 
Private Sub Form_Load()
    'ReDim LongArray(0)
    'ReDim StringArray(0)
    'ReDim DoubleArray(0)
    MsgBox CBool(SafeArrayGetDim(StringArray))
    MsgBox CBool(SafeArrayGetDim(LongArray))
    MsgBox CBool(SafeArrayGetDim(DoubleArray))
End Sub

Решение задачи: «Как узнать инициализирован ли массив?»

textual
                            Листинг программы 
                        

                            Private Declare Function GetMem2 Lib "msvbvm60.dll" (src As Any, dst As Any) As Long
Private Declare Function GetMem4 Lib "msvbvm60.dll" (src As Any, dst As Any) As Long
Private Declare Function memcpy Lib "kernel32.dll" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal length As Long) As Long
 
Public Function IsArrDimmed(vArray As Variant) As Boolean
    IsArrDimmed = (GetArrDims(vArray) > 0)
End Function
 
Public Function GetArrDims(vArray As Variant) As Integer
    Dim ppSA As Long
    Dim pSA As Long
    Dim vt As Long
    Dim sa As SAFEARRAY
    Const vbByRef As Integer = 16384
 
    If IsArray(vArray) Then
        GetMem4 ByVal VarPtr(vArray) + 8, ppSA      ' pV -> ppSA (pSA)
        If ppSA <> 0 Then
            GetMem2 vArray, vt
            If vt And vbByRef Then
                GetMem4 ByVal ppSA, pSA                 ' ppSA -> pSA
            Else
                pSA = ppSA
            End If
            If pSA <> 0 Then
                memcpy sa, ByVal pSA, LenB(sa)
                If sa.pvData <> 0 Then
                    GetArrDims = sa.cDims
                End If
            End If
        End If
    End If
End Function
                        