Как воспроизвести .mp3 файл на Visual Basic 6.0? - VB

Формулировка задачи:

При запуске формы мне нужно воспроизвести .mp3 файл. С форматом .wav я разобрался, вот код:

                    Листинг программы
                
Private Sub Form_Load()
Плеер. DeviceType = "WaveAudio"
Плеер. FileName = "D:\Music\nice.wav"
Плеер. Command = "Open"
Плеер. Command = "Play"
End Sub

Что нужно в коде изменить чтобы проигрывался .mp3 файл? например мне нужно проиграть файл beautiful.mp3, который находится в D:\Music\

Решение задачи: «Как воспроизвести .mp3 файл на Visual Basic 6.0?»

textual
                            Листинг программы 
                        
 
                            
                        
Option Explicit
    Private Declare Function mciSendString Lib "winmm.dll" _
        Alias "mciSendStringA" _
        (ByVal lpstrCommand As String, _
        ByVal lpstrReturnString As String, _
        ByVal uReturnLength As Long, _
        ByVal hwndCallback As Long) As Long
 
    Dim strAliaS As String
 
    Private Sub Command1_Click()
    Dim lngReturn As Long
    Dim strFile As String
    Dim strType As String
 
        ' make sure all working files in memory are closed
        mciSendString "close all", 0, 0, 0
 
        ' set the file path
        strFile = "C:\Program Files\Microsoft Visual Studio\VB_prog\ClavecinNocean.mp3" ' Ваша музыка!
       
        ' make sure the path is in double quote if it contains spaces
        If InStr(strFile, " ") Then
            strFile = Chr(34) & strFile & Chr(34)
        End If
       
        ' create unique alias
        strAliaS = Right(strFile, 3) & Minute(Now)
       
        ' set the file type being passed
        strType = "MPEGVideo"
       
        ' Open the file
        lngReturn = mciSendString("Open " & strFile & " ALIAS " & strAliaS _
            & " Type " & strType & " WAIT", "", 0, 0)
           
        ' Play the file
        lngReturn = mciSendString("Play " & strAliaS, "", 0, 0)
                       
    End Sub
 
    Private Sub Command2_Click()
    Dim lngReturn As Long
 
        If strAliaS = "" Then
            Exit Sub
        End If
       
        ' Stop the file playing
        lngReturn = mciSendString("Stop " & strAliaS, "", 0, 0)
        ' Remove it from memory
        lngReturn = mciSendString("Close " & strAliaS, "", 0, 0)
       
        ' clear the alias
         strAliaS = ""
    End Sub