Начертить Арку / Дугу через три точки? - VB

Формулировка задачи:

Всем привет! В Инете нашёл исходник, по трём точкам чертит круг. Подскажите пожалуйста, как переделать этот код чтобы вырисовывалось вместо Круга, Арка. Т.е. нужно высчитать координаты начала и конца арки. Нужна именно Арка, Кривая Безье не подходит. Заранее спасибо.

Option Explicit
 
Private m_PointNum As Integer
Private m_x(0 To 2)
Private m_y(0 To 2)
 
Private Sub FindCircle(ByVal ax As Single, ByVal ay As Single, ByVal bx As Single, ByVal by As Single, ByVal cx As Single, ByVal cy As Single, ByRef ox As Single, ByRef oy As Single, ByRef radius As Single)
Dim x1 As Single
Dim y1 As Single
Dim dx1 As Single
Dim dy1 As Single
Dim x2 As Single
Dim y2 As Single
Dim dx2 As Single
Dim dy2 As Single
Dim dx As Single
Dim dy As Single
 
    ' Get the perpendicular bisector of (x1, y1) and (x2, y2).
    x1 = (bx + ax) / 2
    y1 = (by + ay) / 2
    dy1 = bx - ax
    dx1 = -(by - ay)
 
    ' Get the perpendicular bisector of (x2, y2) and (x3, y3).
    x2 = (cx + bx) / 2
    y2 = (cy + by) / 2
    dy2 = cx - bx
    dx2 = -(cy - by)
 
    ' See where the lines intersect.
    ox = (y1 * dx1 * dx2 + x2 * dx1 * dy2 - x1 * dy1 * dx2 - y2 * dx1 * dx2) _
        / (dx1 * dy2 - dy1 * dx2)
    oy = (ox - x1) * dy1 / dx1 + y1
 
    dx = ox - ax
    dy = oy - ay
    radius = Sqr(dx * dx + dy * dy)
End Sub
Private Sub Form_Load()
    AutoRedraw = True
End Sub
 
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
Const GAP = 10
 
Dim cx As Single
Dim cy As Single
Dim radius As Single
 
    m_x(m_PointNum) = X
    m_y(m_PointNum) = Y
 
    If m_PointNum = 0 Then
        ' Erase the form.
        Line (0, 0)-Step(ScaleWidth, ScaleHeight), BackColor, BF
    End If
 
    ' Draw the point.
    Line (X - GAP, Y - GAP)-(X + GAP, Y + GAP), vbBlack, BF
 
    If m_PointNum = 2 Then
        m_PointNum = 0
 
        ' Draw the circle.
        On Error Resume Next
        FindCircle m_x(0), m_y(0), _
            m_x(1), m_y(1), m_x(2), m_y(2), _
            cx, cy, radius
        If Err.Number <> 0 Then
            MsgBox "No circle"
        Else
            Circle (cx, cy), radius
        End If
    Else
        m_PointNum = m_PointNum + 1
    End If
End Sub

Решение задачи: «Начертить Арку / Дугу через три точки?»

textual
                            Листинг программы 
                        

                            Option Explicit
 
Private Type Vec
    X As Single
    Y As Single
End Type
 
Dim pt(2) As Vec, cur As Long
 
Private Function GetCircle(p1 As Vec, p2 As Vec, p3 As Vec, r As Single, c As Vec) As Boolean
    Dim m1 As Single, m2 As Single
    If p2.X = p1.X Or p3.X = p2.X Then Exit Function
    m1 = (p2.Y - p1.Y) / (p2.X - p1.X)
    m2 = (p3.Y - p2.Y) / (p3.X - p2.X)
    If m2 = m1 Then Exit Function
    c.X = (m1 * m2 * (p1.Y - p3.Y) + m2 * (p1.X + p2.X) - m1 * (p2.X + p3.X)) / (2 * (m2 - m1))
    c.Y = -(1 / m1) * (c.X - (p1.X + p2.X) / 2) + (p1.Y + p2.Y) / 2
    m1 = p1.X - c.X: m2 = p1.Y - c.Y
    r = Sqr(m1 * m1 + m2 * m2)
    GetCircle = True
End Function
 
Private Sub Form_Load()
    Me.AutoRedraw = True: Me.ScaleMode = vbPixels
    Me.Move (Screen.Width - 8000) \ 2, (Screen.Height - 8000) \ 2, 8000, 8000
    Me.BackColor = vbWhite: Me.ForeColor = vbBlack
End Sub
 
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If cur = 0 Then Me.Cls
    Me.Line (X - 2, Y - 2)-(X + 2, Y + 2), vbRed, B: Print cur + 1
    pt(cur).X = X: pt(cur).Y = Y
    cur = cur + 1
    If cur > 2 Then cur = 0
End Sub
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If cur = 2 Then pt(2).X = X: pt(2).Y = Y: Draw
End Sub
Private Sub Draw()
    Dim a As Single, b As Single, _
        s As Single, e As Single, _
        q As Single, c As Vec, r As Single
        
    If Not GetCircle(pt(0), pt(1), pt(2), r, c) Then Exit Sub
    
    a = -(pt(0).Y - c.Y) * r: b = (pt(0).X - c.X) * r: s = Atan2(a, b)
    a = -(pt(1).Y - c.Y) * r: b = (pt(1).X - c.X) * r: e = Atan2(a, b)
    a = -(pt(2).Y - c.Y) * r: b = (pt(2).X - c.X) * r: q = Atan2(a, b)
    
    If e < 0 Then e = 6.28318530717959 + e
    If s < 0 Then s = 6.28318530717959 + s
    If q < 0 Then q = 6.28318530717959 + q
    
    If s > e Then a = s: s = e: e = a
    If q < s Or q > e Then a = s: s = e: e = a
    
    Debug.Print s, e, q
    Me.Cls
    Circle (c.X, c.Y), r, , s, e
    Me.Line (pt(0).X - 2, pt(0).Y - 2)-(pt(0).X + 2, pt(0).Y + 2), vbRed, B: Print 1
    Me.Line (pt(1).X - 2, pt(1).Y - 2)-(pt(1).X + 2, pt(1).Y + 2), vbRed, B: Print 2
    Me.Line (pt(2).X - 2, pt(2).Y - 2)-(pt(2).X + 2, pt(2).Y + 2), vbRed, B
    Me.Refresh
End Sub
Private Function Atan2(ByVal Y As Double, ByVal X As Double) As Double 'Г‚Г®Г§ГўГ°Г*Г№Г*ГҐГІ ГіГЈГ®Г«, ГІГ*Г*ГЈГҐГ*Г± ГЄГ®ГІГ®Г°Г®ГЈГ® Г°Г*ГўГҐГ* Г®ГІГ*Г®ГёГҐГ*ГЁГѕ Г¤ГўГіГµ ГіГЄГ*Г§Г*Г*Г*Г»Гµ Г·ГЁГ±ГҐГ«
    If Y > 0 Then
        If X >= Y Then
            Atan2 = Atn(Y / X)
        ElseIf X <= -Y Then
            Atan2 = Atn(Y / X) + 3.14159265358979
        Else
            Atan2 = 3.14159265358979 / 2 - Atn(X / Y)
        End If
    Else
        If X >= -Y Then
            Atan2 = Atn(Y / X)
        ElseIf X <= Y Then
            Atan2 = Atn(Y / X) - 3.14159265358979
        Else
            Atan2 = -Atn(X / Y) - 3.14159265358979 / 2
        End If
    End If
End Function
                        