Плавное появление и исчезновение Label - VB

Формулировка задачи:

Срежиссировал вот таким образом: В ролях 2 таймера с именами

Fading

Appearing

, также

Label1

. Цвет формы(что важно):

&H00404040&

Const Interval As Integer = 30     'скорость изменения цвета
 
Dim Showing As Integer

Private Sub Form_Load()
   Showing = 4
   Appearing.Interval = Interval: Fading.Interval = Interval
   Label1.ForeColor = &HF0F0F0: Me.BackColor = &H404040
   Fading.Enabled = True: Appearing.Enabled = False
   Label1.Caption = "Идёт анализ..."
End Sub
 
Private Sub Appearing_Timer()
   Showing = Showing + 1
   Label1.ForeColor = "&H" & Hex(Showing) & "F" & Hex(Showing) & "F" & Hex(Showing) & "F" 'пляшем от 404040 до F0F0F0
   If Showing = 15 Then
      Appearing.Enabled = False
      Fading.Enabled = True
   End If
End Sub
 
Private Sub Fading_Timer()
   Showing = Showing - 1
   Label1.ForeColor = "&H" & Hex(Showing) & "F" & Hex(Showing) & "F" & Hex(Showing) & "F" 'пляшем от F0F0F0 до 404040
   If Showing = 4 Then
      Fading.Enabled = False
      Appearing.Enabled = True
   End If
End Sub
 
Private Sub Label1_Click()
   End
End Sub

Вопрос: Как сделать то же самое без такого извращения? Если фон формы изменится, придётся менять и те эфки, что в кавычках. EXE-файл прилагается. Код формы выше. Мельком вычитал про API-функцию AlphaBlend. Может ли она в этом как-то помочь?

Решение задачи: «Плавное появление и исчезновение Label»

textual
                            Листинг программы 
                        

                            Const Interval As Integer = 30     'скорость изменения цвета
Dim R&, G&, B&
Private Declare Function OleTranslateColor Lib "oleaut32.dll" (ByVal lOleColor As Long, ByVal lHPalette As Long, lColorRef As Long) As Long
 
Private Sub Form_Load()
  OleTranslateColor Me.BackColor, 0, B
  R = B And 255: B = B \ 256
  G = B And 255: B = B \ 256
  Fading.Interval = Interval
  Fading.Enabled = True
  Label1.Caption = "Идёт анализ..."
End Sub
 
Private Sub Fading_Timer()
  Static d&, k&
  Label1.ForeColor = RGB(R + (255 - R) / 15 * d, G + (255 - G) / 15 * d, B + (255 - B) / 15 * d)
  If d = 0 Then
    k = 1
  ElseIf d = 15 Then
    k = -1
  End If
  d = d + k
End Sub
 
Private Sub Label1_Click()
  Unload Me
End Sub
                        