В редакторе кода перестали работать русские символы - VB

Формулировка задачи:

Всем добрый вечер! Может кто посоветует что, слетел русский язык и вместо него набор символов. см. вложение. Всем откликнувшимся спасибо.

Решение задачи: «В редакторе кода перестали работать русские символы»

textual
                            Листинг программы 
                        

                            @echo off
Echo.
Echo Скрипт подмены файла шрифтов c_1251.nls -^> c_1252.nls 
Echo c резервным копированием в c_1252.bak
Echo Используйте для устанения абракодабры в русских шрифтах
Echo при копировании текста через английскую раскладку клавиатуры
Echo.
Setlocal EnableDelayedExpansion
set sys=%windir%\system32
if exist "%sys%\c_1252.bak" (
  choice /M "Патч русского шрифта уже применен. Вы уверены, что хотите продолжить?"
  if !errorlevel!==2 goto :eof
)
Echo.
echo Делаю резервную копию -^> %sys%\c_1252.bak
Set /a Try=1
:Backup
if exist "%sys%\c_1252.nls" (
  if exist "%sys%\c_1252.bak" del /f /q "%sys%\c_1252.bak"
  ren "%sys%\c_1252.nls" c_1252.bak||(
    if !Try!==1 (
        Call :Rights
        Echo.
        Echo Последняя попытка ...
        Goto :Backup
      ) else (
        echo Скрипт не имеет достаточных полномочий. Запустите его от имени Администратора.
        Goto :ex
)))
Echo.
echo Заменяю файл %sys%\c_1252.nls
copy "%sys%\c_1251.nls" "%sys%\c_1252.nls"&&echo Готово.
echo.
echo Для достижения эффекта перезагрузите компьютер.
:ex
echo.
pause
exit /b
 
:Rights
Echo.
echo Получаю права на модификацию файлов шрифтов
for %%a in (c_1251.nls,c_1252.nls,c_1252.bak) do (
  if exist "%sys%\%%a" (
    takeown /f "%sys%\%%a" 1>nul 2>&1
    echo y|1>nul 2>&1 cacls "%sys%\%%a" /e /g %username%:f
    attrib -R -S -H "%sys%\%%a" 1>nul 2>&1
))
Set /a Try+=1
exit /b
                        