Распределение и запись символов в файлы - Assembler

; fasm code...
; Создать символьный файл 'F.txt'.
; Записать в файл 'G.txt' - большие буквы латинского алфавита,
; в файл 'B.txt' - цифры, в файл 'H.txt' - все остальные символы.
; Порядок следования сохранить.
 
org 100h
jmp start
 
mes0      db   13,10,'Create "F.txt" file: $'
mes1      db   13,10,'All file created! Result...',13,10,10,'$'
fName     db   'F.txt',0
 
buffF     db   80                       ; буфер для строки (0Ah)
strLen    db   0                        ;
string    db   80 dup(' ')              ;
buffG     db   32 dup(' '),13,10        ; файловые буфера
buffB     db   32 dup(' '),13,10        ;
buffH     db   32 dup(' '),13,10,'$'    ; выводить на экран будем сразу/три строки
 
start: mov   dx,mes0            ;
       call  message            ;
       mov   ah,0Ah             ; вводим данные в файл-F
       mov   dx,buffF           ;
       int   21h                ;
 
       xor   cx,cx              ;
       mov   dx,fName           ; данные в буфере!
       call  createFile         ; создаём файл F.txt
       mov   cl,[strLen]        ; байт для записи..
       mov   dx,string          ; адрес данных
       call  writeFile          ; запись/закрытие!
 
       mov   cl,[strLen]        ; начинаем сортировку!
       mov   si,string          ; адрес исходной строки
       mov   di,buffG           ; адрес буфера для заглавных
       mov   bx,buffB           ;     ..для цифр
       mov   bp,buffH           ;         ..для остальных
find:  lodsb                    ; читаем из SI
       test  al,100000b         ; проверка на заглавную
       jnz   @@1                ; пропустить если нет
       mov   byte[di],al        ; иначе: сохранить в буфере
       inc   di                 ; сл.позиция в буфере..
       jmp   okey               ; читаем сл.символ из строки
@@1:   cmp   al,'0'             ; фильтр чисел
       jb    @@2                ;
       cmp   al,'9'             ;
       ja    @@2                ;
       mov   byte[bx],al        ; сохранить, если число
       inc   bx                 ;
       jmp   okey
@@2:   mov   byte[bp],al        ; остальное - "в мусорку"
       inc   bp                 ;
okey:  loop  find               ;
 
       mov   byte[fName],'G'    ; меняем букву в имени файла
       mov   dx,fName           ;
       call  createFile         ; создаём файл G.txt
       mov   cx,32              ; байт для записи..
       mov   dx,buffG           ; адрес данных
       call  writeFile          ; запись/закрытие!
 
       mov   byte[fName],'B'    ;
       mov   dx,fName           ;
       call  createFile         ; создаём файл B.txt
       mov   cx,32              ;
       mov   dx,buffB           ;
       call  writeFile          ; запись/закрытие!
 
       mov   byte[fName],'H'    ;
       mov   dx,fName           ;
       call  createFile         ; создаём файл H.txt
       mov   cx,32              ;
       mov   dx,buffH           ;
       call  writeFile          ; запись/закрытие!
 
       mov   dx,mes1            ; выводим все строки на экран
       call  message            ;
       mov   dx,buffG           ;
       call  message            ;
 
exit:  xor   ax,ax              ; ждём клавишу..
       int   16h                ;
       int   20h                ; выход!
 
;ннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннн
message:
       mov   ah,9
       int   21h
       ret
;---------------------------------------------------------------------
createFile:                  ; Создать файл!
        mov   ah,3Ch         ;
        mov   cx,20h         ; атрибут архивный
        int   21h            ;
        ret                  ;
;---------------------------------------------------------------------
writeFile:                   ; Запись в файл!
        mov   bx,ax          ; отправляем дескриптор в BX
        mov   ah,40h         ;
        int   21h            ;
        mov   ah,3Eh         ; Закрыть файл
        int   21h            ;
        ret                  ;