Поиск файла во всех директориях рекурсивно - Turbo Pascal

Формулировка задачи:

программа выполняет поиск по сигнатуре. НО! делает это в одной папке. а как сделать так, чтобы поиск был и во вложенных в эту папку папках?

uses Dos;
type
  buf = array [1..16] of byte;
 
const
  signature:buf = ($0F,$7F,$44,$24,$28,$89,$44,$24,$38,$B8,$17,$00,$00,$00,$49,$8D);
var
  scanF: file;
  block:byte;
  s:searchRec;
  CurDir:string;

procedure findSign(const findFile: string) ;
var i:integer;
begin
assign(scanF, findFile);
  reset(scanF,1);
 i:=1;
  while not EoF(scanF) do
    begin
        blockread(scanF, block, 1);
        if block=signature[i] then
            begin
                if i=16 then                    
                        write(' - НАЙДЕНА СИГНАТУРА!!!');                    
                else  i:=i+1;
            end
        else i:=1;
    end;
close(scanF);
end;
 
begin
chdir('C:\windows\system32');
findFirst('*.*',$01+$02+$04+$20,S);
 while DosError = 0 do
      begin
        if (s.Name<>'.') and (s.Name<>'..') then
            begin
                Write(' файл:',s.Name:14);
            end;
            findSign(s.name);
            FindNext(s);
            writeln;
      end; 
    writeln('Поиск окончен, нажмите "Enter"');
  readln;
end.

Решение задачи: «Поиск файла во всех директориях рекурсивно»

Листинг программы

Uses DOS;
 
Procedure FileFind(Dir,FindName : PathStr);
{Поиск файлов по маске по всему диску}
 
 Procedure SearchDir(Dir : PathStr);
 Var
   SRec       : SearchRec;
 begin
   {Поиск файлов по маске}
   if Dir[Length(Dir)] <> '\' then Dir := Dir+'\';
   FindFirst(Dir + FindName, AnyFile, SRec);
   While DosError = 0 do
     begin
       With SRec do
        if Attr and (VolumeID + Directory) = 0 then
         WriteLn(Dir + Name);
       FindNext(SRec);
     end;
   {Поиск всех вложенных каталогов, в т.ч. скрытых, системных, r/o}
   FindFirst(Dir+'*.*', Directory or ReadOnly or Hidden or SysFile, SRec);
   While DosError = 0 do
     begin
       With SRec do
        if (Attr and Directory <> 0) and (Name[1] <> '.') then
         SearchDir(Dir+Name);
       FindNext(SRec);
     end;
 end;
 
begin
 SearchDir(Dir);
end;
{------------------------------------------}
{Пример поиска всех .TXT файлов на диске С:}
begin
  FileFind('c:\','*.txt');
end.

Объяснение кода листинга программы

Подключается библиотека DOS.
Определяется процедура FileFind, которая выполняет поиск файлов по маске по всему диску.
Определяется процедура SearchDir, которая рекурсивно ищет все файлы по заданной маске в текущей директории и всех ее поддиректориях.
В процедуре SearchDir инициализируется переменная SRec, которая будет использоваться для хранения информации о найденных файлах.
Если последний символ директории не является обратным слэшем (\), то к нему добавляется обратный слэш (\).
Вызывается функция FindFirst с аргументами Dir + FindName, AnyFile и SRec. Эта функция ищет первый файл, соответствующий заданной маске, в указанной директории.
Пока ошибка DOS равна нулю, выполняется цикл. Внутри цикла выводится имя найденного файла.
После каждого вывода имени файла вызывается функция FindNext с переменной SRec.
Если атрибут файла VolumeID + Directory равен нулю, то его имя выводится на экран.
Вызывается функция FindFirst с аргументами Dir + '*.*', Directory or ReadOnly or Hidden or SysFile и SRec. Эта функция ищет все файлы, соответствующие заданной маске, в указанной директории.
Пока ошибка DOS равна нулю, выполняется цикл. Внутри цикла вызывается процедура SearchDir с аргументом Dir + Name. Эта процедура ищет все файлы с именем, совпадающим с указанным, в указанной директории.
Если атрибут файла Directory не равен нулю и его имя не начинается с точки (.'), то вызывается процедура SearchDir с аргументом Dir + Name.
Выполняются действия, описанные в пунктах 6-11.
Конец процедуры SearchDir.
Конец программы.